*This file includes recodes in SPSS for NCVS data analysis regarding demographic characteristics information. 
*Please note that all recodes in this file may not be necessary to run your analysis. The recodes you choose will be based on your analysis.
*Examples of how these recodes were used for analysis can be found in BJS current reports at bjs.ojp.gov.
*For more information about the NCVS, see the BJS website or contact AskBJS at AskBJS@usdoj.gov.
*From July 2016 to June 2019, the question pertaining to sexual orientation was administered to all respondents age 16 or older.
*From July 2019 to December 2021, administration of this question was restricted to victims age 16 or older.
*Beginning in January 2022, this question was administered to all respondents age 16 or older. Therefore, population data for sexual orientation are not available from July 2019 to December 2021.
****************************************************************************************
missing values All().

*Create new variable Year using variable yearq.
compute Year=trunc(yearq).

****************************************************************************************
*Rename variable v3018 to sex using compute.
compute sex   =v3018.
****************************************************************************************
*Create new variable hispanic using variables v3024a and v3024. 
*This variable allowed victims to identify as Hispanic or not.
Do If (Year ge 2014).
+ compute hispanic =v3024a.
Else If (Year lt 2014).
+compute hispanic = v3024.
End If.
****************************************************************************************

recode hispanic(1= 1)            /* Of Hispanic Origin
               (2= 2)            /* Not of Hispanic Origin
               (8=88)            /* Residue
               (9=99)            /* Out of Universe.

recode v3015(5   = 1)            /* Never Married
            (1   = 2)            /* Married
            (2   = 3)            /* Widowed
            (3   = 4)            /* Divorced
            (4   = 5)            /* Separated
            (8   =88)            /* Residue
            (9   =99)            /* Out of Universe
             into marital2.

*Create new variable for age brackets presented in Criminal Victimization bulletin.
recode v3014(12 thru 17= 1)
            (18 thru 24= 2)
            (25 thru 34= 3)
            (35 thru 49= 4)
            (50 thru 64= 5)
            (65 thru 97= 6)
            (98        =88)       /* Residue
            (99        =99)       /* Out of Universe
             into age.


****************************************************************************************
*Create new variable raceEX using variable v3023a.
recode v3023a (1=1)                      /*White
                        (2=2)            /*Black
                        (3=3)            /*American Indian Alaska Native
                        (4=4)            /*Asian
                        (5=5)            /*Native Hawaiian or Other Pacific Islander
                        (6 thru 20=6)	 /*2 Or more races
                        (88=88)
                        (99=99)
                        (Else=-1)
                        into raceEX.


****************************************************************************************
*Create new variable raceethEX using newly created variables raceEX and hispanic. This variable combines Hispanic origin ethnicity
compute raceethEX=0.
If (raceEX=1 And hispanic ne 1) raceethEX=1.                    /*NonHispanic White.
If (raceEX=2 And hispanic ne 1) raceethEX=2.                    /*NonHispanic Black.
If (raceEX=3 And hispanic ne 1) raceethEX=3.                    /*NonHispanic AIAN.
If (raceEX=4 And hispanic ne 1) raceethEX=4.                    /*NonHispanic Asian.
If (raceEX=5 And hispanic ne 1) raceethEX=5.                    /*NonHispanic Native Hawaiian Or other PI.
If (raceEX=6 And hispanic ne 1) raceethEX=6.                    /*NonHispanic 2 Or more races.
If (raceEX=88 And hispanic ne 1) raceethEX=88.
If (raceEX=99 And hispanic ne 1) raceethEX=99.
If (hispanic eq 1) raceethEX=7.                                 /*Hispanic.
If (raceEX=-1) raceethEX=-1.                                    /*INVALID Until 2003 Q1.

****************************************************************************************

*Create new variable raceethex2 using newly created variable raceethex. This variable combines Asian, Native Hawaiian, or Other Pacific Islander
*into one race/ethnicity category and places American Indian and Alaska Native respondents of 2+ races into another category.
Compute raceethex2 = raceethex.
IF (raceethex= 4 or raceethex=5) raceethex2 = 8.
IF (raceethex= 3 or raceethex=6) raceethex2 = 9.
execute.

****************************************************************************************
*Create new variable hincome using variable SC214A. This variable groups SC214A into annual household income brackets.
*These brackets correspond to categories presented in Criminal Victimization bulletin.
recode SC214A(1,2,3,4,5,6,7,8= 1)            /*   Less than $24,999
            (9,10,11,12 = 2)            /* $25,000 To $49,999
            (13,14,15   = 3)            /* $50,000 To $99,999
            (16,17= 4)               /*$100,000 To $199,999
            (18= 5)              /*$200,000 Or more
		(-1=-1) /*invalid before 2015
            (98   =88)            /* Residue
            (99   =99)            /* Out of Universe
             into hincome.
****************************************************************************************

*Education recode that separates high school graduates and advanced degrees.
*Variable available from 2003 forward. Categories changed in 2003 to include advanced degrees and high school graduate.
recode v3020     (lo thru 00 =1)                         /*No schooling
                              (1 thru 5=2)               /*Grade school
                               (6 thru 8=3)              /*Middle school
                               (9 thru 12, 27=4)         /*High school
                               (28=5)                    /*High school graduate
                               (21 thru 26, 40, 41=6)    /*Some college and associate's degree
                               (42=7)                    /*Bachelor's degree
                               (43 thru 45=8)            /*Advanced degree
                               (98=98)                   /*Residue
                               into educate.
if (year le 2002) educate=-1.                            /*Invalid prior to 2003.
execute.

/*Create new sexual orientation variable sexualorient using variable v3084 to obtain sexual orientation values.
compute sexualorient = v3084.

recode v3084(1 = 1)            /* Lesbian or gay
            (2 = 2)            /* Straight
            (3 = 3)            /* Bisexual
            (4 = 4)            /* Something else
            (5 = 5)            /* DK
            (6 = 6)            /* Refused
            (8 = 8)            /*Residue
            (9 = 9)            /*Out of universe
             into sexualorient.
			 
*Variable v3084 was not added to the public-use datafile (PUF) until 2017 so all years prior to 2017 will be invalid -1.
if (year le 2016) sexualorient=-1.        /*Invalid prior to 2017.

****************************************************************************************
*Add variable and value labels to all newly created variables.
VARIABLE LABELS
 sex           'SEX'
 hispanic      'HISPANIC'
 age           'AGE OF VICTIM'
 marital2      'MARITAL STATUS'
 raceEX        'victim race recode'
 raceethEX     'race and Hispanic origin of victim'
 raceethex2    'race and Hispanic origin combining Asian+NHOPI and AIAN+2 or more races'
 hincome       'ANNUAL HOUSEHOLD INCOME'
 educate       'education recode separating out high school graduate and advanced degrees'
 sexualorient  'sexual orientation'.



value labels
 sex      1 'Male'
             2 'Female'/
 hispanic    1 'Hispanic'
             2 'NonHispanic'
            88 'Residue'
            99 'Out of Universe'/
 age         1 '12 - 17'
             2 '18 - 24'
             3 '25 - 34'
             4 '35 - 49'
             5 '50 - 64'
             6 '65 or older'
            88 'Residue'
            99 'Out of Universe'/
 marital2    1 'Never Married'
             2 'Married'
             3 'Widowed'
             4 'Divorced'
             5 'Separated'
            88 'Residue'
            99 'Out of Universe'/
 hincome     -1 'Invalid until 2015Q1'
		1 'Less than $25,000'
             2 '$25,000 to $49,999'
             3 '$50,000 to $99,999'
             4 '$100,000 to $199,999'
             5 '$200,000 or more'
            88 'Residue'
            99 'Out of Universe'/
 educate
            -1 'Invalid until 2003 Q1'
            1 'no schooling'
            2 'grade school'
            3 'middle school'
            4 'high school'
            5 'high school graduate'
            6 'some college and associate degree'
            7 'bachelors degree'
            8 'advanced degree'
            98 'residue'/
 raceEX 
		-1 'Invalid until 2003 Q1'
            1 'White'
            2 'Black'
            3 'AIAN'
            4 'Asian'
            5 'Native Hawaiian or other PI'
            6 '2 or more races'
            88 'Residue'
            99 'Out of universe'/
 raceethEX
           -1 'Invalid until 2003 Q1'
            1 'White nonHispanic'
            2 'Black nonHispanic'
            3 'AIAN nonHispanic'
            4 'Asian nonHispanic'
            5 'Native Hawaiian or other PI nonHispanic'
            6 '2 or more races nonHispanic'
            7 'Hispanic'
            88 'Residue'
            99 'Out of universe'/
 raceethEX2
           -1 'Invalid until 2003 Q1'
            1 'White nonHispanic'
            2 'Black nonHispanic'
            7 'Hispanic'
            8 'Asian and NHOPI'
            9 'AIAN and 2 or more'
            88 'Residue'
            99 'Out of universe'/
 sexualorient      
		1 'Lesbian or gay'
            2 'Straight'
            3 'Bisexual'
            4 'Something else'
            5 'DK'
            6 'Refused'
            8 'Residue'
            9 'Out of universe'
            -1 'invalid until 2017 Q1'/.
Execute.